Excel VBA学习笔记：单元格的characters 属性，取关键字用

单元格的.Characters 属性，常用于取关键字，给关键字标注用于区别的颜色。

语法：Range.Characters(Start, Length)；Start 起始位置，表示从第几个字符起；Length 取几位字符。.Characters返回的是一个对象。

示例：将标红的字符取出，并分段显示。

一般的处理思路：是用循环判断单个字符颜色，再判断红色字符是否连续，有多长，再输出。用到循环嵌套，多重判断。

  Set Rng = Range("A1")
  有红色 = False
  输出计数 = 1
  For i = 1 To Len(Rng.Value)
    n = i    'i 值是标红的起始位置，（n-1）值记录连续标红字符的终止位置
    Do While Rng.Characters(n, 1).Font.Color = vbRed
       n = n + 1
       有红色 = True
       If n > Len(Rng.Value) Then  '防止n 大于字符串长度出错
          Exit Do
       End If
    Loop
    If 有红色 Then   '出现标红字符，进行输出
       Cells(输出计数, "C") = Mid(Rng.Value, i, n - i) 'n-i 就是标红字符的长度
       输出计数 = 输出计数 + 1
       有红色 = False
       i = n - 1    'i值跳到标红字符最后，避免重复判断
     End If
   Next i

其实，反向思考下，将黑色字符都换成“空格”，红色字符就留下了，再以“空格”为分隔，不就得到了所需。这个思路以处理黑色字符为思路。下面代码明显简单清晰多了。

Set Rng = Range("A1")
  For i = 1 To Len(Rng.Value)
    If Rng.Characters(i, 1).Font.Color = vbRed Then
       t = t & Rng.Characters(i, 1).Text  '记录下红色的字符
    Else
      t = t & " "      '黑色的字符都被换成空格
    End If
  Next i
  t = WorksheetFunction.Trim(t)  '调用工作表函数 Trim 对空格进行处理
  arr = Split(t)
  Range("b1").Resize(UBound(arr) + 1, 1) = Application.Transpose(arr)

本示例意在拓展思维，当直接处理数据很麻烦时，反方向考虑下，说不定有奇效。

附：VBA 里去“空格”函数 Trim，LTrim，RTrim

VBA 中Trim 去除字符串头尾部的空格，中间的空格不进行任何处理；

LTrim 本意去掉左边的空格，就是去除位于字符串头部的空格；

RTrim 本意去掉右边的空格，就是去除位于字符串尾部的空格。

而工作表函数Trim，不光去除头尾部的空格，还将字符串中间的连续空格合成 1个空格。

见下图中t1 、 t2值