sum函数定义：求和计算；
官方说明：返回某一单元格区域中数字、逻辑值及数字的文本表达式、直接键入的数字之和；
大白话说明：加法；
使用格式：SUM(number1,number2, ...) ，SUM(列名)，SUM(行名)；
大白话格式：SUM(单个或多个单元格)，SUM(列的名称 如:AA)，SUM(行的名称 如:1:1)；
参数定义：要求和的值,或者值所在的单元格引用。参数用逗号分开.2003版最多指定30个number；
要点：如果参数为数组或引用,只有其中的数字将被计算。数组或引用中的空白单元格、逻辑值、文本将被忽略；
注意事项：
1.如果参数为错误值或为不能转换成数字的文本,将会导致错误。
2.正在求和公式单元格不能包涵在要被求和的单元格内。
3.如果是文本型数字参数,SUM函数是可以直接求和的；如果是引用单元格中的文本型数字(单元格的数字前添加半角单引号“’”),则求和时将忽略。
一、经典用法：
以下公式写法都为一个number(条件)------
| 公式 | 公式显示 | 说明 | |
| 6 | =SUM(6) | 直接键入的数字求和 | |
| 6 | =SUM(B14) | 某一单元格求和 | |
| 12 | =SUM(B14:B15) | 某一单元格区域求和 | |
| 0 | =SUM(Y:Y) | 某一列区域求和 | |
| 0 | =SUM(11:11) | 某一行区域求和 |
以下公式写法都为多个number------
| 公式 | 公式显示 | 说明 | |
| 14 | =SUM(6,8) | 直接键入的多个数字求和 | |
| 26 | =SUM(B14,H14,B15) | 多个单元格求和 | |
| 64 | =SUM(B14:B16,H14:H15) | 多个单元格区域求和 | |
| 8051 | =SUM(C:C,G:G) | 多列区域求和 | |
| #REF! | =SUM(88:88,89:89) | 多行区域求和 | |
| =SUM(表一:表五!B3:B10) | 多工作表同区域求和 本方法仅适用于每个工作表地址一致的情况 [公式说明]：对多表相同区域求和,不需要录入每个工作表的求和地址,只需将第一个工作表名和最后一个表名用冒号连接,后跟"!"与单元格地址,以此作为SUM函数的参数即可.其中"!"表示前面的字符为工作表名称. | ||
| =SUM(’*’!B3) | 快速设置当前表以外的所有工作表相同区域的总和公式 [公式说明]1、公式中两个单引号中间加"*"表示除当前表以外的所有工作表.2、在输入公式后,程序会自动将"’*’"转换成实际的工作表名. |
二、升级用法：
举例示意
注：不使用通配符。
|
1、单区域 |
公式显示 |
| 39 | =SUM(E24:E43) |
|
2、多区 |
|
| 38 | =SUM(E24:E27,E29:E33,E35:E36,E38) |
|
3、单条件 求大于10的数据合计 |
|
| 66 | {=SUM((E24:E43>10)*E24:E43)} |
|
4、多条件 求除去10~20之间的数据合计 注意:这里的"+"是或、或者的意思.此公式是比10小或者比20大. |
|
| -37 | {=SUM(((E24:E43<10)+(E24:E43>20))*E24:E43)} |
|
5、多条件 求10~20之间的数据合计 注意:这里的"*"是且、而且的的意思.此公式是比10大,而且要求比20小. |
|
| 46 | {=SUM(((E24:E43>10)*(E24:E43<20))*E24:E43)} 注意:上面的用的是"+",这里是"*". |
|
6、多条件 <-1或者>5且不等于9的数据之和 |
|
| 3 | {=SUM(((E24:E43<-1)+(E24:E43>5)*(E24:E43<>9))*E24:E43)} |
|
7、多条件 <-1或者>5且不等于9的数据个数 |
|
| 14 | {=SUM((E24:E43<-1)+(E24:E43>5)*(E24:E43<>9))} |
|
8、满足条件的单元格个数 |
|
| 10 | {=SUM((C24:C43="男")*1)} |
|
9、多条件 男性*二组人员数据合计 |
|
| -20 | {=SUM((C24:C43="男")*(D24:D43="二组")*E24:E43)} |
|
10、多条件 姓张的男员工数据合计 |
|
| -35 | {=SUM((LEFT(B24:B43)="张")*(C24:C43="男")*E24:E43)} |
| 11、最大的三个数据合计(前三名合计) | |
| 53 | {=SUM(LARGE(E24:E43,{1,2,3}))} |
|
12、三维求和 连续条件表名的同一坐标合计 |
|
| =SUM(A组:E组!B2:B9) | |
|
13、引用多条件合计 |
|
| 39 | {=SUM((B45:E45=D24:D43)*E24:E43)} |
|
14、计算五个组各自的前三名数据之和 |
|
| {=SUM(LARGE(CHOOSE({1,2,3,4,5},A组!B2:B9,B组!B2:B9,C组!B2:B9,D组!B2:B9,E组!B2:B9),ROW(1:3)))} | |
|
15、多条件数据合计简写方式 |
|
| 2 | {=SUM((D24:D43&C24:C43="一班男")*E24:E43)} |
|
16、重叠区域求和 |
|
| 4 | =SUM(E24:E42 E42:E43) |
|
17、数组乘法 |
|
| 190 | {=SUM(C47:C49*D47:D49)} |
| 190 | =SUMPRODUCT(C47:C49,D47:D49) |
|
18、用ROW得出1加到100的和(主要用于嵌套数组中) |
|
| 6903 | {=SUM(ROW(1:100))} |
|
19、统计单元格字数 |
|
| 14 | {=SUM(LEN(G60:G61))} |
|
20、条件多列累加 |
|
| 20 | {=SUM(IF(B47:B49=B45,C47:D49))} |
文本举例示意(附加）
|
21、文本数字求和(减负法) 注意:减负法说明详见 |
|
| 52 | {=SUM(--C65:D67)} |
| 0 | =SUM(C65:D67) |
|
文本数字求和(乘法) |
|
| 52 | {=SUM(C65:D67*1)} |
|
文本数字求和(加法) |
|
| 52 | {=SUM(C65:D67+0)} |
|
文本数字求和(除法) |
|
| 52 | {=SUM(C65:D67/1)} |
|
文本数字求和(减法) |
|
| 52 | {=SUM(C65:D67-0)} |
|
22、文本数字求个数 |
|
| 2 | {=SUM(1*(--C65:D67>9))} |
|
23、文本数字条件求和 |
|
| 26 | {=SUM((--C65:D67>9)*C65:D67)} |
|
24、奇数相加 |
|
| -1 | {=SUM(IF(MOD(E24:E43,2),E24:E43))} |
|
25、偶数相加 |
|
| 40 | {=SUM(IF(MOD(E24:E43,2)<>1,E24:E43))} |
补充示意
| 26、提取两位数数组相加 | |
| 155 | =SUM(--RIGHT(B84:B88,2)) |
三、突破2003版SUM求和最多指定30个number极限的方法，是在SUM前面加二个括号：
| 36个参数相加 | 公式显示（.....表示省略了相同项） |
| 0 | =SUM((A93,A93,A93,......)) |
四、不同工作表同一单元格(坐标)相加：
如果工作表中有三个工作表Sheet1、Sheet2、Sheet3,你在Sheet1表中输入这个公式:=SUM(’*’!A1)，回车，
公式自动变成=SUM(Sheet2:sheet3!A1)。
大概到这里吧，公式中略有嵌套，希望大家勿喷。
没有涉及到的用法欢迎在评论中讨论或回复哦~
粉笔灰！！！
相互学习，共同提高！