“话说天下大势，分久必合，合久必分”这是三国演义第一回合的话，在股市里面道理同在，股市下跌久了必然上涨，上涨久了必然下跌。何时由下跌转为上涨，何时由上涨转为下跌呢？
今天我给大家分享一个定量结构底部背驰的实战运用，运用市场运行规律，用MACD技术指标量化标准，寻找底部结构。
底部结构定义：趋势类指标macd出现了临峰或者隔峰背驰——股价创新低，而macd不创新低，对应的dif数字不创新低，就代表个股出现了底部背驰钝化，当dif数值拐头向上时，底部结构形成；可以判断该股有可能止跌，容易出现比较好的买点。
深圳成指经一年多的定量结构点，如图：
实战个股案例：
300159新研股份——2019年1月3日底部结构形成。
1月3日底分型形成，并且股价站稳5日均线买入：
之后连续3天上涨累积最高超过15%。
使用该策略需要注意的几个重要点：
1、日线级别的底部结构，对应的上涨基本上是日线的一笔，所以买入需要等待底部结构形成信号。
2、日线个股形成底分型k线组合，阳线最好是成交量放大且收盘价站稳5日均线。
3、切换到该股30分钟或者60分钟最好也是出现了底部结构（一般早于日线底部结构形成），这样可以形成多周期底部结构，从而出现多周期上涨共振。
4、大盘指数最好也能够出现至少60分钟以上级别的底部结构或者大盘指数已经站稳5日均线。
5、如果只是为了短线获利，建议超过10%以上涨幅可以选 择获利了结。
6、如果出现结构消失——形成底分型之后，股价再次跌破底分型收盘价最低位置，dif值重新拐头向下时，需要及时止损。
技术指标公式及选股运用
公式代码：
DIF:100*(EMA(CLOSE,12)-EMA(CLOSE,26));
DEA:EMA(DIF,9);
MACD:(DIF-DEA)*2,COLORSTICK;
{底部结构预警}
死叉:=CROSS(DEA,DIF);
N1:=BARSLAST(死叉),NODRAW;{最近一次死叉的位置}
N2:=REF(BARSLAST(死叉),N1+1),NODRAW;{倒数第二次死叉与倒数第一次死叉的区间}
N3:=REF(BARSLAST(死叉),N2+N1+2),NODRAW;{倒数第三次死叉与倒数第二次死叉的区间}
CL1:=LLV(C,N1+1),NODRAW;{最近一次死叉后，最低收盘价}
DIFL1:=LLV(DIF,N1+1),NODRAW;
CL2:=REF(CL1,N1+1),NODRAW;{倒数第二次死叉与倒数第一次死叉之间的最低收盘价}
DIFL2:=REF(DIFL1,N1+1),NODRAW;
CL3:=REF(CL2,N1+1),NODRAW;{倒数第三次死叉与倒数第二次死叉之间的最低收盘价}
DIFL3:=REF(DIFL2,N1+1),NODRAW;
PDIFL2:=IF(DIFL2>0,INTPART(LOG(DIFL2))-1,INTPART(LOG(-DIFL2))-1);
MDIFL2:=INTPART(DIFL2/POW(10,PDIFL2));
PDIFL3:=IF(DIFL3>0,INTPART(LOG(DIFL3))-1,INTPART(LOG(-DIFL3))-1);
MDIFL3:=INTPART(DIFL3/POW(10,PDIFL3));
MDIFB2:=INTPART(DIF/POW(10,PDIFL2));
MDIFB3:=INTPART(DIF/POW(10,PDIFL3));
直接底背离:=(CL1<CL2 ) AND (MDIFB2>MDIFL2) AND (MACD<0 AND REF(MACD,1)<0) AND MDIFB2<=REF(MDIFB2,1);
隔峰底背离:=(CL1<CL3 AND CL3<CL2 ) AND (MDIFB3>MDIFL3) AND (MACD<0 AND REF(MACD,1)<0) AND MDIFB3<=REF(MDIFB3,1);
B:直接底背离 OR 隔峰底背离,NODRAW;
BG:((MDIFB2>REF(MDIFB2,1))*REF(直接底背离,1)) OR ((MDIFB3>REF(MDIFB3,1))*REF(隔峰底背离,1)),NODRAW;
{DRAWTEXT(TFILTER(B,(REF(DIF,1)>REF(DIF,2) AND DIF<REF(DIF,1)),1),DIFL2,'钝化开始'),COLORYELLOW;}
STICKLINE(B,DIF,DEA,1,0),COLORRED;
DRAWTEXT(TFILTER(BG,C<REF(CL1,1),1),DIF*0.98,'结构形成'),COLORMAGENTA;
{顶部结构预警}
金叉:=CROSS(DIF,DEA);
M1:=BARSLAST(金叉),NODRAW;{最近一次金叉的位置}
M2:=REF(BARSLAST(金叉),M1+1),NODRAW;{倒数第二次金叉与倒数第一次金叉的区间}
M3:=REF(BARSLAST(金叉),M2+M1+2),NODRAW;{倒数第三次金叉与倒数第二次金叉的区间}
CH1:=HHV(C,M1+1),NODRAW;{最近一次金叉后，最高收盘价}
DIFH1:=HHV(DIF,M1+1),NODRAW;
CH2:=REF(CH1,M1+1),NODRAW;{倒数第二次金叉与倒数第一次金叉之间的最高收盘价}
DIFH2:=REF(DIFH1,M1+1),NODRAW;
CH3:=REF(CH2,M1+1),NODRAW;{倒数第三次金叉与倒数第二次金叉之间的最高收盘价}
DIFH3:=REF(DIFH2,M1+1),NODRAW;
PDIFH2:=IF(DIFH2>0,INTPART(LOG(DIFH2))-1,INTPART(LOG(-DIFH2))-1);
MDIFH2:=INTPART(DIFH2/POW(10,PDIFH2));
PDIFH3:=IF(DIFH3>0,INTPART(LOG(DIFH3))-1,INTPART(LOG(-DIFH3))-1);
MDIFH3:=INTPART(DIFH3/POW(10,PDIFH3));
MDIFT2:=INTPART(DIF/POW(10,PDIFH2));
MDIFT3:=INTPART(DIF/POW(10,PDIFH3));
直接顶背离:=(CH1>CH2 ) AND (MDIFT2<MDIFH2) AND (MACD>0 AND REF(MACD,1)>0) AND MDIFT2>=REF(MDIFT2,1);
隔峰顶背离:=(CH1>CH3 AND CH3>CH2 ) AND (MDIFT3<MDIFH3) AND (MACD>0 AND REF(MACD,1)>0) AND MDIFT3>=REF(MDIFT3,1);
T:直接顶背离 OR 隔峰顶背离,NODRAW;
TG:((MDIFT2<REF(MDIFT2,1))*REF(直接顶背离,1)) OR ((MDIFT3<REF(MDIFT3,1))*REF(隔峰顶背离,1)),NODRAW;
{DRAWTEXT(TFILTER(T,(REF(DIF,1)<REF(DIF,2) AND DIF>REF(DIF,1)),1),DIFH2,'钝化开始'),COLORYELLOW;}
STICKLINE(T,DIF,DEA,1,0),COLORGREEN;
DRAWTEXT(TFILTER(TG,C>REF(CH1,1),1),DIF*1.02,'结构形成'),COLORMAGENTA;
公式运用：
只要是通达信的交易看盘软件,顶部菜单栏——功能——公式系统——公式管理器——选择要把公式放入的子栏目（建议使用：用户——其他类型——点击新建），复制上面代码粘贴，确定即可。如图：
建立起技术指标之后，需要在个股界面——指标栏找出之前设定的指标名称即可。
选股运用：
选股使用方法：功能——选股器——综合选股——其他类型——定量结构完整——修改具体参数。如图:
注意：选出的股票需要确定买点，底分型越强越好。
选股展示：
2019年1月14选股结果
股市有风险，入市需谨慎，本文所涉及的个股只限于技术总结，不构成任何推荐，据此操作，风险自担！